Salesforce API（9）Web服务

公开一个类作为REST服务

使您的Apex类可用作REST Web服务非常简单。定义您的类为全局，并将方法定义为全局静态。为类和方法添加注释。例如，此示例Apex REST类使用一种方法。 getRecord方法是一个自定义的REST API调用。它使用@HttpGet进行注释，并被GET请求调用。

@RestResource(urlMapping='/Account/*')
global with sharing class MyRestResource {
    @HttpGet
    global static Account getRecord() {
        // 添加你的代码
    }
}

URL映射区分大小写，可以包含通配符（*）。

将每个暴露的方法定义为全局静态，并添加注释以将其与HTTP方法相关联。以下注释可用。每个Apex类中只能使用一次每个注释。

公开一个类作为SOAP服务

使您的Apex类作为SOAP Web服务可用，就像使用REST一样简单。将您的课程定义为全球课程。将webservice关键字和静态定义修饰符添加到您要公开的每个方法。 webservice关键字提供对其添加方法的全局访问权限。

例如，这里有一个方法的示例类。 getRecord方法是一个定制的SOAP API调用，它返回一个Account记录。

global with sharing class MySOAPWebService {
    webservice static Account getRecord(String id) {
        // 添加你的代码
    }
}

使用PUT方法更新数据

您添加到CaseManager类的upsertCase方法实现了PUT操作。这里包括这个方法供您参考。该方法使用内置的upsert Apex DML方法通过匹配ID值来创建或覆盖大小写记录字段。如果在请求的主体中发送了一个ID，则会使用它填充案例sObject。否则，创建没有ID的案例sObject。 upsert方法用填充的case sObject调用，DML语句做其余部分。瞧！

@HttpPut
global static ID upsertCase(String subject, String status,
    String origin, String priority, String id) {
    Case thisCase = new Case(
        Id=id,
        Subject=subject,
        Status=status,
        Origin=origin,
        Priority=priority);
    // 通过Id匹配大小写，如果存在的话。
    // 否则，创建新的案例。
    upsert thisCase;
    // 返回案例ID。
    return thisCase.Id;
}

使用PATCH方法更新数据

作为PUT方法的替代方法，使用PATCH方法更新记录字段。你可以用不同的方式实现PATCH方法。一种方法是在方法中指定参数以更新每个字段。例如，您可以创建一个方法来更新具有以下签名的案例的优先级：updateCasePriority（String priority）。要更新多个字段，可以列出所有需要的字段作为参数。

提供更多灵活性的另一种方法是将字段作为请求主体中的JSON名称/值对传递。这种方法可以接受任意数量的参数，并且参数在方法的签名中不固定。这种方法的另一个优点是没有字段被意外清除，因为是空的。您添加到CaseManager类的updateCaseFields方法使用第二种方法。此方法将请求正文中的JSON字符串反序列化为名称/值对映射，并使用sObject PUT方法设置字段。

@HttpPatch
global static ID updateCaseFields() {
    RestRequest request = RestContext.request;
    String caseId = request.requestURI.substring(
        request.requestURI.lastIndexOf('/')+1);
    Case thisCase = [SELECT Id FROM Case WHERE Id = :caseId];
    // 将JSON字符串反序列化为名称 - 值对
    Map<String, Object> params = (Map<String, Object>)JSON.deserializeUntyped(request.requestbody.tostring());
    // 遍历每个参数字段和值
    for(String fieldName : params.keySet()) {
        // 设置Case sObject的字段和值
        thisCase.put(fieldName, params.get(fieldName));
    }
    update thisCase;
    return thisCase.Id;
}

// 设置一个测试请求
RestRequest request = new RestRequest();

// 设置请求属性
request.requestUri =
    'https://yourInstance.salesforce.com/services/apexrest/Cases/'
    + recordId;
request.httpMethod = 'GET';

// 设置其他属性，如参数
request.params.put('status', 'Working');

// 更令人敬畏的代码在这里...
// 最后，如果使用，将请求分配给RestContext
RestContext.request = request;

现在，让我们将整个课程保存在Developer Console中，然后运行结果。

1. 在开发者控制台中，选择 File | New | Apex Class.
2. 对于类名称，输入CaseManagerTest，然后单击 OK.
3. 将自动生成的代码替换为以下类定义。

   @IsTest
   private class CaseManagerTest {
   
       @isTest static void testGetCaseById() {
           Id recordId = createTestRecord();
           // 设置一个测试请求
           RestRequest request = new RestRequest();
           request.requestUri =
               'https://yourInstance.salesforce.com/services/apexrest/Cases/'
               + recordId;
           request.httpMethod = 'GET';
           RestContext.request = request;
           // 调用测试方法
           Case thisCase = CaseManager.getCaseById();
           // 验证结果
           System.assert(thisCase != null);
           System.assertEquals('Test record', thisCase.Subject);
       }
   
       @isTest static void testCreateCase() {
           // 调用测试方法
           ID thisCaseId = CaseManager.createCase(
               'Ferocious chipmunk', 'New', 'Phone', 'Low');
           // 验证结果
           System.assert(thisCaseId != null);
           Case thisCase = [SELECT Id,Subject FROM Case WHERE Id=:thisCaseId];
           System.assert(thisCase != null);
           System.assertEquals(thisCase.Subject, 'Ferocious chipmunk');
       }
   
       @isTest static void testDeleteCase() {
           Id recordId = createTestRecord();
           // 设置一个测试请求
           RestRequest request = new RestRequest();
           request.requestUri =
               'https://yourInstance.salesforce.com/services/apexrest/Cases/'
               + recordId;
           request.httpMethod = 'GET';
           RestContext.request = request;
           // 调用测试方法
           CaseManager.deleteCase();
           // 验证记录被删除
           List<Case> cases = [SELECT Id FROM Case WHERE Id=:recordId];
           System.assert(cases.size() == 0);
       }
   
       @isTest static void testUpsertCase() {
           // 1.插入新记录
           ID case1Id = CaseManager.upsertCase(
                   'Ferocious chipmunk', 'New', 'Phone', 'Low', null);
           // 验证新记录是否已创建
           System.assert(Case1Id != null);
           Case case1 = [SELECT Id,Subject FROM Case WHERE Id=:case1Id];
           System.assert(case1 != null);
           System.assertEquals(case1.Subject, 'Ferocious chipmunk');
           // 2. 将现有记录的状态更新为Working
           ID case2Id = CaseManager.upsertCase(
                   'Ferocious chipmunk', 'Working', 'Phone', 'Low', case1Id);
           // 验证记录已更新
           System.assertEquals(case1Id, case2Id);
           Case case2 = [SELECT Id,Status FROM Case WHERE Id=:case2Id];
           System.assert(case2 != null);
           System.assertEquals(case2.Status, 'Working');
       }    
   
       @isTest static void testUpdateCaseFields() {
           Id recordId = createTestRecord();
           RestRequest request = new RestRequest();
           request.requestUri =
               'https://yourInstance.salesforce.com/services/apexrest/Cases/'
               + recordId;
           request.httpMethod = 'PATCH';
           request.addHeader('Content-Type', 'application/json');
           request.requestBody = Blob.valueOf('{"status": "Working"}');
           RestContext.request = request;
           // 将现有记录的状态更新为Working
           ID thisCaseId = CaseManager.updateCaseFields();
           // 验证记录已更新
           System.assert(thisCaseId != null);
           Case thisCase = [SELECT Id,Status FROM Case WHERE Id=:thisCaseId];
           System.assert(thisCase != null);
           System.assertEquals(thisCase.Status, 'Working');
       }  
   
       // Helper method
       static Id createTestRecord() {
           // Create test record
           Case caseTest = new Case(
               Subject='Test record',
               Status='New',
               Origin='Phone',
               Priority='Medium');
           insert caseTest;
           return caseTest.Id;
       }          
   
   }

4. 按下CTRL + S保存。
5. 通过选择测试|运行您的组织中的所有 Test | Run All.

测试结果显示在“测试”选项卡中。测试执行完成后，请检查“总体代码覆盖率”窗格中的CaseManager行。这是在100％的覆盖面。

Apex REST支持的数据类型

Apex REST支持这些数据类型的参数和返回值。

• Apex基元（不包括sObject和Blob）。
• sObjects
• Apex基元或sObjects的列表或映射（仅支持使用String键的映射）。
• 用户定义的类型包含上面列出的类型的成员变量。

Apex REST端点中的命名空间

Apex REST端点中的命名空间
Apex REST方法可用于托管和非托管包中。调用托管包中包含的Apex REST方法时，需要将托管包名称空间包含在REST调用URL中。例如，如果该类包含在名为packageNamespace的托管包名称空间中，并且Apex REST方法使用/ MyMethod / *的URL映射，则通过REST调用这些方法的URL将采用https：// instance形式。 salesforce.com/services/apexrest/packageNamespace/MyMethod/。

自定义Apex Web服务和Salesforce API

外部应用程序可以使用Salesforce的REST和SOAP API与Salesforce集成，而不是使用REST和SOAP服务的自定义Apex代码。这些API使您可以创建，更新和删除记录。但是，使用Apex Web服务的优势在于Apex方法可以封装复杂的逻辑。这个逻辑对消费应用程序是隐藏的。此外，Apex类操作可能比单独调用API更快，因为在客户端和Salesforce服务器之间执行的往返次数较少。通过Apex Web服务调用，仅发送一个请求，并且方法中的所有操作都在服务器上执行。

Apex Web服务的安全注意事项

Apex Web服务方法运行的安全上下文与Salesforce API的安全上下文不同。与Salesforce API不同，Apex Web服务方法以系统权限运行，并且不尊重用户的对象和字段权限。但是，Apex Web服务方法在使用with sharing关键字声明时会强制执行共享规则。