Salesforce API（7）REST外调

先决条件

在编写测试之前，让我们创建一个类，其中包含我们在“将数据发送到服务”单元中匿名执行的GET和POST请求示例。这些示例稍有修改，以便请求在方法和返回值中，但它们与前面的示例基本相同。

使用StaticResourceCalloutMock测试标注

要测试您的标注，请通过实现接口或使用静态资源来使用模拟标注。在这个例子中，我们稍后使用静态资源和模拟接口。静态资源包含要返回的响应主体。同样，使用模拟标注时，请求不会发送到端点。相反，Apex运行时知道查找在静态资源中指定的响应，并返回它。 Test.setMock方法通知运行时在测试方法中使用模拟标注。让我们看看模拟标注在行动。首先，我们创建一个包含JSON格式字符串的静态资源，用于GET请求。

1. 在开发者控制台中，选择 File | New | Static Resource.
2. 对于名称，输入GetAnimalResource。
3. 对于MIME类型，即使我们使用JSON，也请选择text / plain。
4. 点击 Submit.
5. 在为资源打开的选项卡中，插入以下内容。确保它全部在一行上，不会中断到下一行。这个内容是模拟标注返回的内容。这是三个林地生物阵列。

   {"animals": ["pesky porcupine", "hungry hippo", "squeaky squirrel"]}

6. 按下CTRL + S保存。

您已成功创建您的静态资源！现在，让我们为使用此资源的标注添加一个测试。

1. 在开发者控制台中，选择 File | New | Apex Class.
2. 对于类名称，输入AnimalsCalloutsTest，然后单击 OK.
3. 将自动生成的代码替换为以下测试类定义。

   @isTest
   private class AnimalsCalloutsTest {
   
       @isTest static  void testGetCallout() {
           // 基于静态资源创建模拟响应
           StaticResourceCalloutMock mock = new StaticResourceCalloutMock();
           mock.setStaticResource('GetAnimalResource');
           mock.setStatusCode(200);
           mock.setHeader('Content-Type', 'application/json;charset=UTF-8');
           // 将标注与模拟响应相关联
           Test.setMock(HttpCalloutMock.class, mock);
           // 调用方法来测试
           HttpResponse result = AnimalsCallouts.makeGetCallout();
           // 验证模拟响应不为空
           System.assertNotEquals(null,result,
               'The callout returned a null response.');
           // 验证状态码
           System.assertEquals(200,result.getStatusCode(),
             'The status code is not 200.');
           // 验证内容类型
           System.assertEquals('application/json;charset=UTF-8',
             result.getHeader('Content-Type'),
             'The content type value is not expected.');  
           // 验证数组包含3个项目 
           Map<String, Object> results = (Map<String, Object>) 
               JSON.deserializeUntyped(result.getBody());
           List<Object> animals = (List<Object>) results.get('animals');
           System.assertEquals(3, animals.size(),
             'The array should only contain 3 items.');          
       }   
   
   }

4. 按下CTRL + S保存。
5. 选择 Test | Always Run Asynchronously.如果不选择“始终运行异步”，则测试运行只包含一个同步运行的类。您只能从“测试”选项卡打开日志，以进行同步测试运行。
6. 要运行测试，请选择 Test | New Run.
7. 从Test Classes列表中选择 AnimalsCalloutsTest.
8. 点击 Add Selected | Run.

测试结果显示在测试运行ID下的测试选项卡中。测试执行完成后，展开测试运行以查看详细信息。现在在“代码总体覆盖率”窗格中双击AnimalCallouts，查看测试覆盖了哪些行。

用HttpCalloutMock测试标注

为了测试你的POST标注，我们提供了一个HttpCalloutMock接口的实现。此接口使您能够指定在响应方法中发送的响应。您的测试类指示Apex运行时通过再次调用Test.setMock来发送此假响应。对于第一个参数，传递HttpCalloutMock.class。对于第二个参数，传递一个AnimalsHttpCalloutMock的新实例，它是您的HttpCalloutMock的接口实现。 （在这个例子之后的例子中，我们将写AnimalsHttpCalloutMock）

Test.setMock(HttpCalloutMock.class, new AnimalsHttpCalloutMock());

1. 在开发者控制台中，选择 File | New | Apex Class.
2. 对于类名，输入AnimalsHttpCalloutMock，然后单击 OK.
3. 将自动生成的代码替换为以下类定义。

   @isTest
   global class AnimalsHttpCalloutMock implements HttpCalloutMock {
       // 实现这个接口方法
       global HTTPResponse respond(HTTPRequest request) {
           // 创建一个假的回应
           HttpResponse response = new HttpResponse();
           response.setHeader('Content-Type', 'application/json');
           response.setBody('{"animals": ["majestic badger", "fluffy bunny", "scary bear", "chicken", "mighty moose"]}');
           response.setStatusCode(200);
           return response; 
       }
   }

4. 按下CTRL + S保存。

在您的测试类中，创建testPostCallout方法来设置模拟标注，如下例所示。 testPostCallout方法调用Test.setMock，然后调用AnimalsCallouts类中的makePostCallout方法。然后验证返回的响应是您在模拟实现的响应方法中指定的。

1. 修改测试类AnimalsCalloutsTest添加第二个测试方法。单击类选项卡，然后在右括号之前添加以下方法。

   @isTest static void testPostCallout() {
       // 设置模拟标注类
       Test.setMock(HttpCalloutMock.class, new AnimalsHttpCalloutMock()); 
       //这会导致从实现HttpCalloutMock的类发送假响应。 
       HttpResponse response = AnimalsCallouts.makePostCallout();
       // Verify that the response received contains fake values
       String contentType = response.getHeader('Content-Type');
       System.assert(contentType == 'application/json');
       String actualValue = response.getBody();
       System.debug(response.getBody());
       String expectedValue = '{"animals": ["majestic badger", "fluffy bunny", "scary bear", "chicken", "mighty moose"]}';
       System.assertEquals(actualValue, expectedValue);
       System.assertEquals(200, response.getStatusCode());
   }

2. 按下CTRL + S保存。
3. 选择 Test | New Run.
4. 从Test Classes列表中选择 AnimalsCalloutsTest.
5. 点击 Add Selected | Run.

   测试结果显示在“测试”选项卡下的新测试运行ID下。当测试执行完成时，展开测试运行以查看有关这两个测试的详细信息。